Define initial value 
The initial value is given as a symmetric complex matrix with positive definite imaginary part

AA = a + I α;

    BB  =  b  +  I β;

    CC  =  c  +  I γ;

    CN2[a_] := ComplexExpand[Re[a]^2 + Im[a]^2]

H0 = {{AA, BB}, {BB, CC}};
Hr = {{a, b}, {b, c}};
Hi = {{α, β}, {β, γ}};
H0  //  MatrixForm

In this particular case, we can solve G explicitly:

G[t_] :=  
      H0 . Inverse[
          IdentityMatrix[2]  +  
            H0 t]


      
FullSimplify[D[G[t], t] + G[t] . G[t]]

The shape operator is given as the real part of G. We shall only study its trace and determinant. These
determine the curvatures of the phase front:

Gr[t_] := FullSimplify[ComplexExpand[Re[G[t]]]]
Gi[t_] := 
      FullSimplify[
        ComplexExpand[Im[G[t]]]]

  
K[t_] :=  Together[Det[Gr[t]]]  
  
S[t_] :=  1/2 Together[Tr[Gr[t]]]

K is a rational function. Let num and den be the numerator and denumerator:

FullSimplify[K[t]]
FullSimplify[S[t]]

Constants:

Our goal is to write K(t) and S(t) using simpler formulas. To do this we need the following constants:

C0 = 
      ComplexExpand[
Det[
          ComplexExpand[
            Re[H0]]]
]
C1 = 2 Tr[ComplexExpand[Re[H0]]]
C2 = 
      ComplexExpand[
(
Tr[Re[H0]]^2 + 
            2  Det[ComplexExpand[Re[H0]]]  +  Tr[Im[H0]]^2 - 
            2  Det[ComplexExpand[
                  Im[H0]]]
)
]
C3 = 
      ComplexExpand[
2 (c CN2[AA] +  a CN2[CC] - 
              Re[BB^2 Tr[
                    ComplexExpand[
                      Conjugate[
                        H0]]] ])
]
C4 = CN2[Det[H0]]

Check expression for K(t)

num = Numerator[K[t]];
den = Denominator[K[t]];

These are 2nd and 4th order polynomials:

Collect[num, t]
Collect[den, t]

Simplify[
      num - 
(
C4 t^2 +  
            1/2 C3 t  +   C0
)]
Simplify[
      den - 
(
 
          C4 t^4 +  C3 t^3  +   C2 t^2  +  C1 t  + 
            1
)]

Check expression for S(t)

num = Numerator[S[t]];
den = Denominator[S[t]];

These are 3rd and 4th order polynomials:

Collect[num, t]
Collect[den, t]

Simplify[
      num - 
(
2 C4 t^3  + 
            3/2 C3 t^ 2  + C2 t  +  
            1/2 C1
)]
Simplify[
      den - 
(
 
          2 (C4 t^4 +  C3 t^3  +   C2 t^2  +  C1 t  + 
                1)
)]

Done!